2H NMR on Varian INOVA600

Use regular 5 mm BB or 3 mm BB probe to acquire 2H spectrum, you have to disable the lock channel. Just disconnect the lock cable form the probe and then turn off lock (set the lock power and lock gain to zero and click lock off). In this case, there is no lock for the experiment and the peaks will shift because of manget drifting during the acquisition. Most 2H NMR spectrum has acquire more than three hours, the magnet drifting will be about few hz, this is not accetable. The best way to solve the problm as following:

1. Use FID shimming (since there is no lock solvent in the sample). set up proton type gf and then go to shim on the FID.

2. acquite 2H spectrum in a array mode. acquire 512 scans (about 20 mins) for each increament. The drift is under 1 hz on our instrument. We could acquire more than 12 hours, after save the spectrum, we could correct the drift and add them together as a sum spectrum.

3. Remove the H2 reject filter on the LB channel. Otherwise you will not see the 2H signal.

4. Set the temperature to minimize the drifting.

Procedure to Acquire the Spectrum:

a. Install the 3 mm BB probe. Tune on H1, H2, disconnect the H2 reject filter, change 1/4 cable.

b. Insert D2O standard, load shim file and use gradient shim on proton. 0.4/6/12 should be OK.

c. Calibrate 90 degree pulse ( 8.4us at 56 for proton and 10 us at 54 for H2)

d. Set proton FID shim in exp2 and setup H2 acquisition exp3. setup the temperature (50C in our case) in both experiment.

e. load the real sample, temperature, shim, lock off, spin on, proton decoupling on (dpwr=38 -40, dmf=10000, dof center of proton spectrum)

f. set the at=1.2, ss=8 sw=8 ppm etc. array d1, start value 1, increament 0 total 20 (depends time and SN requirement) time for the total time.

g. after complete, svf('H2_12345_date').

h. jexp6, load the file, and type driftsum, file name:H2_12345_data; The sum spectrum will be displayed in the exp5. svf('H2_12345_date_sum'). this will be the sum fid. you could process it as regular 1D spectrum.

i. The driftsum macro:

jexp1 "use exp1 to get data "
input('filename? '):$filename "prompt for filename"
rt($filename) "assumes you are in the correct directory"
lb=1 wft aph0 f full "process arrayed data"
$spectdc=1
repeat
select($spectdc)
dc "baseline correct data"
$spectdc=$spectdc+1
until $spectdc > celem

select(1) ds peak:$ht,cr $first=cr "select 1st spectrum, get ACN peak position"
select(celem) ds peak:$ht,cr $last=cr "select last spectrum, get ACN peak position"
$drift=($first - $last)/celem "calcualte drift rate"
write('line3',$drift)

clradd "clear buffer exp5"
$spect=1
repeat
select($spect)
lsfrq=$drift * ($spect - 1) "load each fid and shift frequency"
add "add to exp5"
$spect=$spect+1
until $spect > celem

jexp5 "go to exp5"
wft dc vsadj "take a look "
$filename = $filename+'_'+'sum' "save summed data"
svf($filename)
*********

Put this file in the /vnmr/maclib and make sure set it to executable for all users. mode 755 driftsum.